Пост старый, надо полагать автору не актуальный... Но может кому пригодится.
Измерение емкости (в попугаях, но при желании можно откалибровать) с помощью ESP8266 и одного резистора (100к от сенсора на землю для емкостей порядка 0-50пФ)
Для больших емкостей нужно меньший "разрядный" резистор и добавить токоограничивающий от пина до сенсора (или измеряемого кондея если использовать как измеритель)
Методика измерения типовая.
1. Заряжаем кондей (тач сенсор) устанавливая 1 на выход
2. Переключаем выход в режим входа и измеряем время разрядки (по смене 1 на 0)
Через Arduino.h цепляются нужные макросы типа GPC и т.д. Сразу скажу, с pinMode/digitalWrite/digitalRead для малых емкостей (тач сенсора) работать НЕ будет! Т.к. эти функции слишком медленные.
#include <Arduino.h>
#include <user_interface.h>
#define IO_PIN 12
#define GPIO_IN ( (volatile uint32_t *)0x60000318 )
void ICACHE_RAM_ATTR setup() {
pinMode( IO_PIN, OUTPUT );
Serial.begin( 74880 );
system_soft_wdt_stop();
*( (volatile uint32_t *)0x60000900 ) &= ~( 1 ); // Hardware WDT OFF
uint32_t pinMask = 1 << IO_PIN;
uint32_t timeCount = 0;
digitalWrite( IO_PIN, 1 ); // Важно! Это состояние будет сохраняться в регистре и выводиться на пин при смене INPUT/OUTPUT
uint32_t sampleCount = 65536;
uint32_t sampleNo = 0;
while ( true ) {
sampleNo++; //Работает с переполнением. Вычисление среднего и вывод каждые sampleNo % sampleCount замеров
// Быстрый аналог pinMode( IO_PIN, OUTPUT );
// При переводе в режим OUTPUT на выход пойдет высокий уровень (установленный в строке 15), т.к. значение в регистре _сохраняется_ при смене OUTPUT на INPUT и обратно
//GPF( IO_PIN ) = GPFFS( GPFFS_GPIO( IO_PIN ) ); //Set mode to GPIO //В _данном случае_ лишнее, т.к. не меняется при смене направления IN/OUT порта
GPC( IO_PIN ) = ( GPC( IO_PIN ) & ( 0xF << GPCI ) ); //SOURCE(GPIO) | DRIVER(NORMAL) | INT_TYPE(UNCHANGED) | WAKEUP_ENABLE(DISABLED)
GPES = ( 1 << IO_PIN ); //Enable
// Быстрый аналог pinMode( IO_PIN, INPUT );
//GPF( IO_PIN ) = GPFFS( GPFFS_GPIO( IO_PIN ) ); //Set mode to GPIO //В _данном случае_ лишнее, т.к. не меняется при смене направления IN/OUT порта
GPEC = ( 1 << IO_PIN ); //Disable
GPC( IO_PIN ) = ( GPC( IO_PIN ) & ( 0xF << GPCI ) ) | ( 1 << GPCD ); //SOURCE(GPIO) | DRIVER(OPEN_DRAIN) | INT_TYPE(UNCHANGED) | WAKEUP_ENABLE(DISABLED)
while ( ( *GPIO_IN & pinMask ) != 0 ) { // Этот вариант самый быстрый из найденных (соотв. выше точность измерения интервала)
//while ( GPIP( IO_PIN ) != 0 ) { //digitalRead();
timeCount++;
}
if ( ( sampleNo % sampleCount ) == 0 ) { //Вываливаем результат каждые sampleCount замеров
Serial.print( "TC: " );
Serial.print( timeCount );
Serial.print( "; L: " );
Serial.println( timeCount / sampleCount );
timeCount = 0;
ESP.wdtFeed();
}
}
}
void loop() {
}
