#include <Arduino.h>
#include <ArduinoJson.h>
#ifdef ARDUINO_ARCH_ESP8266
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#define WebServerImpl ESP8266WebServer
#elif ARDUINO_ARCH_ESP32
#include <WiFi.h>
#include <WebServer.h>
#define WebServerImpl WebServer
#else
#error Unsupported architecture, use ARDUINO_ARCH_ESP8266 or ARDUINO_ARCH_ESP32
#endif
// Это ip адрес по которому будет доступен веб-сервер
IPAddress local_ip(192, 168, 4, 22);
// Это ip адрес шлюза, этот шлюз будут использовать wifi клиенты подключившиеся к точке доступа
IPAddress gateway (192, 168, 4, 9);
// Это маска подсети
IPAddress subnet (255, 255, 255, 0);
// Экземпляр веб-сервера
WebServerImpl server(80);
// Это обработчик для запроса корневого url
void handle_root() {
// Отвечаем текстом что выполнен запрос корневого url
server.send(200, "text/plain", "This is response for root url.");
}
// Это обработчик для url /my-status
void handle_my_status() {
// Строим документ
StaticJsonDocument<256> doc;
// Добавляем строковый элемент с именем "some_text" и значением "bla-bla"
doc["some_text"] = "bla-bla";
// Добавляем числовой элемент с именем "my_millis" и значением полученных millis
doc["my_millis"] = millis();
String output;
// Серилизуем в строку
serializeJson(doc, output);
// Отправляем ответ клиенту
server.send(200, "application/json", output);
}
// Это обработчик для всех остальных запросов
void handle_not_found() {
// Отвечаем запросившему всё что мы о нем думаем
// и отправляем обратно то, что он прислал в запросе.
String message = "File Not Found\n\n";
// Добавляем uri
message += "URI: ";
message += server.uri();
// Добавляем запрошенный метод
message += "\nMethod: ";
message += server.method() == HTTP_GET ? "GET" : "POST";
// Если в строке запроса есть ещё аргументы, добавим их в сообщение
if (server.args() > 0) {
message += "\nArguments: ";
// Указываем сколько было аргументов
message += server.args();
message += "\n";
// Добавляем аргументы 'ключ: значение'
for (uint8_t i = 0; i < server.args(); i++){
message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
}
}
// Отправляем ответ
server.send(404, "text/plain", message);
}
void setup() {
// Инициализируем wifi
// Отключаем сохранение параметров во флеш
WiFi.persistent(false);
// Выключаем wifi совсем
WiFi.mode(WIFI_OFF);
// Зачем-то спим немножко
delay(100);
// Устанавливаем параметры ip для интерфейса AP
WiFi.softAPConfig(local_ip, gateway, subnet);
// Выбираем режим работы wifi
WiFi.mode(WIFI_AP);
// Задаем идентификатор SSID
WiFi.softAP("MY-ESP");
// Настраиваем веб-сервер
// Устанавливаем обработчик корневого url
server.on("/", HTTP_GET, handle_root);
// Устанавливаем обработчик для url /my-status
server.on("/my-status", HTTP_GET, handle_my_status);
// Устанавливаем обработчик для всего остального не обработанного
server.onNotFound(handle_not_found);
// Запускаем сервер
server.begin();
}
void loop() {
// Даем серверу обрабатывать запросы
server.handleClient();
}
